- Qt 5.5
- Qt Widgets
- Plug & Paint Example
- plugandpaint.pro Example File
- Qt 5.5.1 Reference Documentation

# plugandpaint.pro Example File

tools/plugandpaint/plugandpaint.pro

    QT += widgets

    HEADERS        = interfaces.h \
                     mainwindow.h \
                     paintarea.h \
                     plugindialog.h
    SOURCES        = main.cpp \
                     mainwindow.cpp \
                     paintarea.cpp \
                     plugindialog.cpp

    LIBS           = -Lplugins -lpnp_basictools

    if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
       mac:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)_debug
       win32:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)d
    }

    # install
    target.path = $$[QT_INSTALL_EXAMPLES]/widgets/tools/plugandpaint
    INSTALLS += target